// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target,dialog;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;

	reset_dialog();
	add_dialog_str(0,"The Chief seems happy to see you, but also surprised.  Did he doubt that you would succeed?  Also, strangely enough, he's covered in dried blood.",0);
	if(party_size() > 1){
		add_dialog_str(1,"_Brave, brave Speres.  We are honored by all of you returning victorious.  While your brother in arms failed at his task to protect our livelihood, you all have succeeded.",0);
	}
	else{
		add_dialog_str(1,"_Brave, brave Spere.  We are honored by you returning victorious.  While your brother in arms failed at his task to protect our livelihood, you have succeeded.",0);
	}
	add_dialog_str(2,"_The spirits were with us while you were searching for the gem.  Our crops will now thrive evermore._",0);
	add_dialog_str(3,"_Now, though, it is back in our hands, and I can feel pride in leading this tribe once more.  You did your job well, and everyone in Emerald Valley thanks you._",0);
	add_dialog_str(4,"_Now come!  Let us descend into the cave and put the Aquos Gem back in its proper location._",0);
	add_dialog_str(5,"Chief Licgan and Wiseman Barbarus both descend into the cave.",0);
	add_dialog_choice(0,"Okay.");
	dialog = run_dialog(1);
	erase_char(30);
	erase_char(31);
	set_terrain(20,22,32);
	activate_hidden_group(15);
	end();

break;